GODT-1667: bridge-gui spawns bridge process. [skip-ci]

Other: renaming of bridge-gui. WIP: locate bridge exe. WIP: bridge process launch. WIP: cleaner closure of bridge. WIP: grpcClient connection retries. WIP: clean exit when bridge process is killed. Fixed issues from MR review. [skip-ci]. WIP: Fixed gRPC case in CMakelists.txt [skip-ci] It caused issues on Debian. WIP: update gRPC/protobuf and tweaked CMakeLists.txt. [skip-ci] WIP: Fixed a bug where splash screen could not be dismissed. [skip-ci]
2025-12-20 09:06:45 +00:00 · 2022-07-11 11:09:30 +02:00
parent 7a633ee8c8
commit 72708d6e2c
155 changed files with 4734 additions and 4199 deletions
--- a/internal/frontend/bridge-gui/qml/LocalCacheSettings.qml
+++ b/internal/frontend/bridge-gui/qml/LocalCacheSettings.qml
@ -0,0 +1,149 @@
+// Copyright (c) 2022 Proton AG
+//
+// This file is part of Proton Mail Bridge.
+//
+// Proton Mail Bridge is free software: you can redistribute it and/or modify
+// it under the terms of the GNU General Public License as published by
+// the Free Software Foundation, either version 3 of the License, or
+// (at your option) any later version.
+//
+// Proton Mail Bridge is distributed in the hope that it will be useful,
+// but WITHOUT ANY WARRANTY; without even the implied warranty of
+// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+// GNU General Public License for more details.
+//
+// You should have received a copy of the GNU General Public License
+// along with Proton Mail Bridge. If not, see <https://www.gnu.org/licenses/>.
+
+import QtQuick 2.13
+import QtQuick.Layouts 1.12
+import QtQuick.Controls 2.13
+import QtQuick.Controls.impl 2.13
+import QtQuick.Dialogs 1.1
+
+import Proton 4.0
+
+SettingsView {
+    id: root
+
+    fillHeight: false
+
+    property var notifications
+    property bool _diskCacheEnabled: true
+    property url _diskCachePath: pathDialog.shortcuts.home
+
+    Label {
+        colorScheme: root.colorScheme
+        text: qsTr("Local cache")
+        type: Label.Heading
+        Layout.fillWidth: true
+    }
+
+    Label {
+        colorScheme: root.colorScheme
+        text: qsTr("Bridge stores your encrypted messages locally to optimize communication with your client.")
+        type: Label.Body
+        color: root.colorScheme.text_weak
+        Layout.fillWidth: true
+        Layout.maximumWidth: this.parent.Layout.maximumWidth
+        wrapMode: Text.WordWrap
+    }
+
+    SettingsItem {
+        colorScheme: root.colorScheme
+        text: qsTr("Enable local cache")
+        description: qsTr("Recommended for optimal performance.")
+        type: SettingsItem.Toggle
+        checked: root._diskCacheEnabled
+        onClicked: root._diskCacheEnabled = !root._diskCacheEnabled
+
+        Layout.fillWidth: true
+    }
+
+    SettingsItem {
+        colorScheme: root.colorScheme
+        text: qsTr("Current cache location")
+        actionText: qsTr("Change location")
+        description: root.backend.goos === "windows" ?
+                         root._diskCachePath.toString().replace("file:///", "").replace(new RegExp("/", 'g'), "\\") + "\\" :
+                         root._diskCachePath.toString().replace("file://", "") + "/"
+        descriptionWrap: Text.WrapAnywhere
+        type: SettingsItem.Button
+        enabled: root._diskCacheEnabled
+        onClicked: {
+            pathDialog.open()
+        }
+
+        Layout.fillWidth: true
+
+        FileDialog {
+            id: pathDialog
+            title: qsTr("Select cache location")
+            folder: root._diskCachePath
+            onAccepted: root._diskCachePath = pathDialog.fileUrl
+            selectFolder: true
+        }
+    }
+
+    RowLayout {
+        spacing: 12
+
+        Button {
+            id: submitButton
+            colorScheme: root.colorScheme
+            text: qsTr("Save and restart")
+            enabled: (
+                root.backend.diskCachePath != root._diskCachePath ||
+                root.backend.isDiskCacheEnabled != root._diskCacheEnabled
+            )
+            onClicked: {
+                root.submit()
+            }
+        }
+
+        Button {
+            colorScheme: root.colorScheme
+            text: qsTr("Cancel")
+            onClicked: root.back()
+            secondary: true
+        }
+
+        Connections {
+            target: root.backend
+
+            onChangeLocalCacheFinished: {
+                submitButton.loading = false
+                root.setDefaultValues()
+            }
+        }
+    }
+
+    onBack: {
+        root.setDefaultValues()
+    }
+
+    function submit(){
+        if (!root._diskCacheEnabled && root.backend.isDiskCacheEnabled) {
+            root.notifications.askDisableLocalCache()
+            return
+        }
+
+        if (root._diskCacheEnabled && !root.backend.isDiskCacheEnabled) {
+            root.notifications.askEnableLocalCache(root._diskCachePath)
+            return
+        }
+
+        // Not asking, only changing path
+        submitButton.loading = true
+        root.backend.changeLocalCache(root.backend.isDiskCacheEnabled, root._diskCachePath)
+    }
+
+    function setDefaultValues(){
+        root._diskCacheEnabled = root.backend.isDiskCacheEnabled
+        root._diskCachePath = root.backend.diskCachePath
+    }
+
+    onVisibleChanged: {
+        root.setDefaultValues()
+    }
+}