GODT-1667: bridge-gui spawns bridge process. [skip-ci]

Other: renaming of bridge-gui. WIP: locate bridge exe. WIP: bridge process launch. WIP: cleaner closure of bridge. WIP: grpcClient connection retries. WIP: clean exit when bridge process is killed. Fixed issues from MR review. [skip-ci]. WIP: Fixed gRPC case in CMakelists.txt [skip-ci] It caused issues on Debian. WIP: update gRPC/protobuf and tweaked CMakeLists.txt. [skip-ci] WIP: Fixed a bug where splash screen could not be dismissed. [skip-ci]
2025-12-20 00:56:47 +00:00 · 2022-07-11 11:09:30 +02:00
parent 7a633ee8c8
commit 72708d6e2c
155 changed files with 4734 additions and 4199 deletions
--- a/internal/frontend/bridge-gui/qml/NotificationDialog.qml
+++ b/internal/frontend/bridge-gui/qml/NotificationDialog.qml
@ -0,0 +1,119 @@
+// Copyright (c) 2022 Proton AG
+//
+// This file is part of Proton Mail Bridge.
+//
+// Proton Mail Bridge is free software: you can redistribute it and/or modify
+// it under the terms of the GNU General Public License as published by
+// the Free Software Foundation, either version 3 of the License, or
+// (at your option) any later version.
+//
+// Proton Mail Bridge is distributed in the hope that it will be useful,
+// but WITHOUT ANY WARRANTY; without even the implied warranty of
+// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+// GNU General Public License for more details.
+//
+// You should have received a copy of the GNU General Public License
+// along with Proton Mail Bridge. If not, see <https://www.gnu.org/licenses/>.
+
+import QtQml 2.12
+import QtQuick 2.12
+import QtQuick.Layouts 1.12
+import QtQuick.Controls 2.12
+
+import Proton 4.0
+import Notifications 1.0
+
+Dialog {
+    id: root
+
+    property var notification
+
+    shouldShow: notification && notification.active && !notification.dismissed
+    modal: true
+
+    default property alias data: additionalChildrenContainer.children
+
+    ColumnLayout {
+        spacing: 0
+
+        Image {
+            Layout.alignment: Qt.AlignHCenter
+
+            sourceSize.width: 64
+            sourceSize.height: 64
+
+            Layout.preferredHeight: 64
+            Layout.preferredWidth: 64
+
+            Layout.bottomMargin: 16
+
+            visible: source != ""
+
+            source: {
+                if (!root.notification) {
+                    return ""
+                }
+
+                switch (root.notification.type) {
+                    case Notification.NotificationType.Info:
+                    return "./icons/ic-info.svg"
+                    case Notification.NotificationType.Success:
+                    return "./icons/ic-success.svg"
+                    case Notification.NotificationType.Warning:
+                    case Notification.NotificationType.Danger:
+                    return "./icons/ic-alert.svg"
+                }
+            }
+        }
+
+        Label {
+            Layout.alignment: Qt.AlignHCenter
+            Layout.bottomMargin: 8
+            colorScheme: root.colorScheme
+            text: root.notification.title
+            type: Label.LabelType.Title
+        }
+
+        Label {
+            Layout.fillWidth: true
+            Layout.preferredWidth: 240
+            Layout.bottomMargin: 16
+
+            colorScheme: root.colorScheme
+            text: root.notification.description
+            wrapMode: Text.WordWrap
+            horizontalAlignment: Text.AlignHCenter
+            type: Label.LabelType.Body
+            onLinkActivated: Qt.openUrlExternally(link)
+        }
+
+        Item {
+            id: additionalChildrenContainer
+
+            Layout.fillWidth: true
+            Layout.bottomMargin: 16
+
+            visible: children.length > 0
+
+            implicitHeight: additionalChildrenContainer.childrenRect.height
+            implicitWidth: additionalChildrenContainer.childrenRect.width
+        }
+
+        ColumnLayout {
+            spacing: 8
+            Repeater {
+                model: root.notification.action
+                delegate: Button {
+                    Layout.fillWidth: true
+
+                    colorScheme: root.colorScheme
+                    action: modelData
+
+                    secondary: index > 0
+
+                    loading: modelData.loading
+                }
+            }
+        }
+    }
+}