GODT-1667: bridge-gui spawns bridge process. [skip-ci]

Other: renaming of bridge-gui. WIP: locate bridge exe. WIP: bridge process launch. WIP: cleaner closure of bridge. WIP: grpcClient connection retries. WIP: clean exit when bridge process is killed. Fixed issues from MR review. [skip-ci]. WIP: Fixed gRPC case in CMakelists.txt [skip-ci] It caused issues on Debian. WIP: update gRPC/protobuf and tweaked CMakeLists.txt. [skip-ci] WIP: Fixed a bug where splash screen could not be dismissed. [skip-ci]
2025-12-21 01:26:48 +00:00 · 2022-07-11 11:09:30 +02:00
parent 7a633ee8c8
commit 72708d6e2c
155 changed files with 4734 additions and 4199 deletions
--- a/internal/frontend/bridge-gui/qml/SMTPSettings.qml
+++ b/internal/frontend/bridge-gui/qml/SMTPSettings.qml
@ -0,0 +1,120 @@
+// Copyright (c) 2022 Proton AG
+//
+// This file is part of Proton Mail Bridge.
+//
+// Proton Mail Bridge is free software: you can redistribute it and/or modify
+// it under the terms of the GNU General Public License as published by
+// the Free Software Foundation, either version 3 of the License, or
+// (at your option) any later version.
+//
+// Proton Mail Bridge is distributed in the hope that it will be useful,
+// but WITHOUT ANY WARRANTY; without even the implied warranty of
+// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+// GNU General Public License for more details.
+//
+// You should have received a copy of the GNU General Public License
+// along with Proton Mail Bridge. If not, see <https://www.gnu.org/licenses/>.
+
+import QtQuick 2.13
+import QtQuick.Layouts 1.12
+import QtQuick.Controls 2.13
+import QtQuick.Controls.impl 2.13
+
+import Proton 4.0
+
+SettingsView {
+    id: root
+
+    fillHeight: false
+
+    Label {
+        colorScheme: root.colorScheme
+        text: qsTr("SMTP connection mode")
+        type: Label.Heading
+        Layout.fillWidth: true
+    }
+
+    Label {
+        colorScheme: root.colorScheme
+        text: qsTr("Changes require reconfiguration of email client. Bridge will automatically restart.")
+        type: Label.Body
+        color: root.colorScheme.text_weak
+        Layout.fillWidth: true
+        Layout.maximumWidth: this.parent.Layout.maximumWidth
+        wrapMode: Text.WordWrap
+    }
+
+    ColumnLayout {
+        spacing: 16
+
+        ButtonGroup{ id: protocolSelection }
+
+        Label {
+            colorScheme: root.colorScheme
+            text: qsTr("SMTP connection security")
+        }
+
+        RadioButton {
+            id: sslButton
+            colorScheme: root.colorScheme
+            ButtonGroup.group: protocolSelection
+            text: qsTr("SSL")
+        }
+
+        RadioButton {
+            id: starttlsButton
+            colorScheme: root.colorScheme
+            ButtonGroup.group: protocolSelection
+            text: qsTr("STARTTLS")
+        }
+    }
+
+    Rectangle {
+        Layout.fillWidth: true
+        height: 1
+        color: root.colorScheme.border_weak
+    }
+
+    RowLayout {
+        spacing: 12
+
+        Button {
+            id: submitButton
+            colorScheme: root.colorScheme
+            text: qsTr("Save and restart")
+            onClicked: {
+                submitButton.loading = true
+                root.submit()
+            }
+
+            enabled: sslButton.checked !== root.backend.useSSLforSMTP
+        }
+
+        Button {
+            colorScheme: root.colorScheme
+            text: qsTr("Cancel")
+            onClicked: root.back()
+            secondary: true
+        }
+
+        Connections {
+            target: root.backend
+
+            onToggleUseSSLFinished: submitButton.loading = false
+        }
+    }
+
+    function submit(){
+        submitButton.loading = true
+        root.backend.toggleUseSSLforSMTP(sslButton.checked)
+    }
+
+    function setDefaultValues(){
+        sslButton.checked = root.backend.useSSLforSMTP
+        starttlsButton.checked = !root.backend.useSSLforSMTP
+    }
+
+    onVisibleChanged: {
+        root.setDefaultValues()
+    }
+}