mirror of
https://github.com/ProtonMail/proton-bridge.git
synced 2025-12-19 16:46:55 +00:00
c11fe3e1ab
WIP: updates WIP: cache on disk and autostart. WIP: mail, keychain and more. WIP: updated grpc version in go mod file. WIP: user list. WIP: RPC service placeholder WIP: test C++ RPC client skeleton. Other: missing license script update. WIP: use Qt test framework. WIP: test for app and login calls. WIP: test for update & cache on disk calls. WIP: tests for mail settings calls. WIP: all client tests. WIP: linter fixes. WIP: fix missing license link. WIP: update dependency_license script for gRPC and protobuf. WIP: removed unused file. WIP: app & login event streaming tests. WIP: update event stream tests. WIP: completed event streaming tests. GODT-1554: qt C++ frontend skeleton. WIP: C++ backend declaration. wip: started drafting user model. WIP: users. not functional. WIP: invokable methods WIP: Exception class + backend 'injection' into QML. WIP: switch to VCPKG to ease multi-arch compilation, C++ RPC client skeleton. WIP: Renaming and reorganisation WIP:introduced new 'grpc' go frontend. WIP: Worker & Oveerseer for thread management. WIP: added log to C++ app. WIP: event stream architecture on Go side. WIP: event parsing and streamer stopping. WIP: Moved grpc to frontend subfolder + use vcpkg for gRPC and protobuf. WIP: windows building ok WIP: wired a few messages WIP: more wiring. WIP: Fixed imports after rebase on top of devel. WIP: wired some bool and string properties. WIP: more properties. WIP: wired cache on disk stuff WIP: connect event watcher. WIP: login WIP: fix showSplashScreen WIP: Wired login calls. WIP: user list. WIP: Refactored main(). WIP: User retrieval . WIP: no shared pointer in user model. WIP: fixed user count. WIP: cached goos. WIP: Wired autostart WIP: beta channel toggle wired. WIP: User removal WIP: wired theme WIP: implemented configure apple mail. WIP: split mode. WIP: fixed user updates. WIP: fixed Quit from tray icon WIP: wired CurrentEmailClient WIP: wired UseSSLForSMTP WIP: wired change ports . WIP: wired DoH. . WIP: wired keychain calls. WIP: wired autoupdate option. WIP: QML Backend clean-up. WIP: cleanup. WIP: moved user related files in subfolder. . WIP: User are managed using smart pointers. WIP: cleanup. WIP: more cleanup. WIP: mail events forwarding WIP: code inspection tweaks from CLion. WIP: moved QML, cleanup, and missing copyright notices. WIP: Backend is not QMLBackend. Other: fixed issues reported by Leander. [skip ci]
318 lines
11 KiB
QML
318 lines
11 KiB
QML
// Copyright (c) 2022 Proton AG
|
|
//
|
|
// This file is part of Proton Mail Bridge.
|
|
//
|
|
// Proton Mail Bridge is free software: you can redistribute it and/or modify
|
|
// it under the terms of the GNU General Public License as published by
|
|
// the Free Software Foundation, either version 3 of the License, or
|
|
// (at your option) any later version.
|
|
//
|
|
// Proton Mail Bridge is distributed in the hope that it will be useful,
|
|
// but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
// GNU General Public License for more details.
|
|
//
|
|
// You should have received a copy of the GNU General Public License
|
|
// along with Proton Mail Bridge. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
|
|
import QtQuick 2.13
|
|
import QtQuick.Layouts 1.12
|
|
import QtQuick.Controls 2.12
|
|
import QtQuick.Controls.impl 2.12
|
|
|
|
import Proton 4.0
|
|
|
|
Item {
|
|
id:root
|
|
|
|
property ColorScheme colorScheme
|
|
property var backend
|
|
property var user
|
|
property string address
|
|
|
|
signal dismissed()
|
|
signal finished()
|
|
|
|
implicitHeight: children[0].implicitHeight
|
|
implicitWidth: children[0].implicitWidth
|
|
|
|
|
|
ListModel {
|
|
id: clients
|
|
property string name : "Apple Mail"
|
|
property string iconSource : "./icons/ic-apple-mail.svg"
|
|
property bool haveAutoSetup: true
|
|
property string link: "https://protonmail.com/bridge/applemail"
|
|
|
|
Component.onCompleted : {
|
|
if (root.backend.goos == "darwin") {
|
|
append({
|
|
"name" : "Apple Mail",
|
|
"iconSource" : "./icons/ic-apple-mail.svg",
|
|
"haveAutoSetup" : true,
|
|
"link" : "https://protonmail.com/bridge/applemail"
|
|
})
|
|
append({
|
|
"name" : "Microsoft Outlook",
|
|
"iconSource" : "./icons/ic-microsoft-outlook.svg",
|
|
"haveAutoSetup" : false,
|
|
"link" : "https://protonmail.com/bridge/outlook2019-mac"
|
|
})
|
|
}
|
|
if (root.backend.goos == "windows") {
|
|
append({
|
|
"name" : "Microsoft Outlook",
|
|
"iconSource" : "./icons/ic-microsoft-outlook.svg",
|
|
"haveAutoSetup" : false,
|
|
"link" : "https://protonmail.com/bridge/outlook2019"
|
|
})
|
|
}
|
|
|
|
append({
|
|
"name" : "Mozilla Thunderbird",
|
|
"iconSource" : "./icons/ic-mozilla-thunderbird.svg",
|
|
"haveAutoSetup" : false,
|
|
"link" : "https://protonmail.com/bridge/thunderbird"
|
|
})
|
|
|
|
append({
|
|
"name" : "Other",
|
|
"iconSource" : "./icons/ic-other-mail-clients.svg",
|
|
"haveAutoSetup" : false,
|
|
"link" : "https://protonmail.com/bridge/clients"
|
|
})
|
|
|
|
}
|
|
}
|
|
|
|
Rectangle {
|
|
anchors.fill: root
|
|
color: root.colorScheme.background_norm
|
|
}
|
|
|
|
StackLayout {
|
|
id: guidePages
|
|
anchors.fill: parent
|
|
anchors.leftMargin: 80
|
|
anchors.rightMargin: 80
|
|
anchors.topMargin: 30
|
|
anchors.bottomMargin: 70
|
|
|
|
|
|
ColumnLayout { // 0: Client selection
|
|
id: clientView
|
|
Layout.fillHeight: true
|
|
|
|
property int columnWidth: 268
|
|
|
|
spacing: 8
|
|
|
|
Label {
|
|
colorScheme: root.colorScheme
|
|
text: qsTr("Setting up email client")
|
|
type: Label.LabelType.Heading
|
|
}
|
|
|
|
Label {
|
|
colorScheme: root.colorScheme
|
|
text: address
|
|
color: root.colorScheme.text_weak
|
|
type: Label.LabelType.Lead
|
|
}
|
|
|
|
RowLayout {
|
|
Layout.topMargin: 32-clientView.spacing
|
|
spacing: 24
|
|
|
|
ColumnLayout {
|
|
id: clientColumn
|
|
Layout.alignment: Qt.AlignTop
|
|
|
|
Label {
|
|
id: labelA
|
|
colorScheme: root.colorScheme
|
|
text: qsTr("Choose an email client")
|
|
type: Label.LabelType.Body_semibold
|
|
}
|
|
|
|
ListView {
|
|
id: clientList
|
|
Layout.fillHeight: true
|
|
width: clientView.columnWidth
|
|
|
|
model: clients
|
|
|
|
highlight: Rectangle {
|
|
color: root.colorScheme.interaction_default_active
|
|
radius: ProtonStyle.context_item_radius
|
|
}
|
|
|
|
delegate: Item {
|
|
implicitWidth: clientRow.width
|
|
implicitHeight: clientRow.height
|
|
|
|
ColumnLayout {
|
|
id: clientRow
|
|
width: clientList.width
|
|
|
|
RowLayout {
|
|
Layout.topMargin: 12
|
|
Layout.bottomMargin: 12
|
|
Layout.leftMargin: 16
|
|
Layout.rightMargin: 16
|
|
|
|
ColorImage {
|
|
source: model.iconSource
|
|
height: 36
|
|
sourceSize.height: 36
|
|
}
|
|
|
|
Label {
|
|
colorScheme: root.colorScheme
|
|
Layout.leftMargin: 12
|
|
text: model.name
|
|
type: Label.LabelType.Body
|
|
}
|
|
}
|
|
|
|
Rectangle {
|
|
Layout.fillWidth: true
|
|
Layout.preferredHeight: 1
|
|
color: root.colorScheme.border_weak
|
|
}
|
|
}
|
|
|
|
MouseArea {
|
|
anchors.fill: parent
|
|
cursorShape: Qt.PointingHandCursor
|
|
onClicked: {
|
|
clientList.currentIndex = index
|
|
if (!model.haveAutoSetup) {
|
|
root.setupAction(1,index)
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
ColumnLayout {
|
|
id: actionColumn
|
|
visible: clientList.currentIndex >= 0 && clients.get(clientList.currentIndex).haveAutoSetup
|
|
Layout.alignment: Qt.AlignTop
|
|
|
|
Label {
|
|
colorScheme: root.colorScheme
|
|
text: qsTr("Choose configuration mode")
|
|
type: Label.LabelType.Body_semibold
|
|
}
|
|
|
|
ListView {
|
|
id: actionList
|
|
Layout.fillHeight: true
|
|
width: clientView.columnWidth
|
|
|
|
model: [
|
|
qsTr("Configure automatically"),
|
|
qsTr("Configure manually"),
|
|
]
|
|
|
|
highlight: Rectangle {
|
|
color: root.colorScheme.interaction_default_active
|
|
radius: ProtonStyle.context_item_radius
|
|
}
|
|
|
|
delegate: Item {
|
|
implicitWidth: children[0].width
|
|
implicitHeight: children[0].height
|
|
|
|
ColumnLayout {
|
|
width: actionList.width
|
|
|
|
Label {
|
|
Layout.topMargin: 20
|
|
Layout.bottomMargin: 20
|
|
Layout.leftMargin: 16
|
|
Layout.rightMargin: 16
|
|
colorScheme: root.colorScheme
|
|
text: modelData
|
|
type: Label.LabelType.Body
|
|
}
|
|
|
|
Rectangle {
|
|
Layout.fillWidth: true
|
|
Layout.preferredHeight: 1
|
|
color: root.colorScheme.border_weak
|
|
}
|
|
}
|
|
|
|
MouseArea {
|
|
anchors.fill: parent
|
|
cursorShape: Qt.PointingHandCursor
|
|
onClicked: {
|
|
actionList.currentIndex = index
|
|
root.setupAction(index,clientList.currentIndex)
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
Item { Layout.fillHeight: true }
|
|
|
|
Button {
|
|
colorScheme: root.colorScheme
|
|
text: qsTr("Set up later")
|
|
flat: true
|
|
|
|
onClicked: {
|
|
root.setupAction(-1,-1)
|
|
if (user) {
|
|
user.setupGuideSeen = true
|
|
}
|
|
root.dismissed()
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
function setupAction(actionID,clientID){
|
|
if (user) {
|
|
user.setupGuideSeen = true
|
|
}
|
|
|
|
switch (actionID) {
|
|
case -1: root.dismissed(); break; // dismiss
|
|
case 0: // automatic
|
|
if (user) {
|
|
switch (clientID) {
|
|
case 0:
|
|
root.user.configureAppleMail(root.address)
|
|
break;
|
|
}
|
|
}
|
|
root.finished()
|
|
break;
|
|
case 1: // manual
|
|
var clientObj = clients.get(clientID)
|
|
if (clientObj != undefined && clientObj.link != "" ) {
|
|
Qt.openUrlExternally(clientObj.link)
|
|
} else {
|
|
console.log("unexpected client index", actionID, clientID)
|
|
}
|
|
root.finished();
|
|
break;
|
|
default:
|
|
console.log("unexpected client setup action", actionID, clientID)
|
|
}
|
|
}
|
|
|
|
function reset(){
|
|
guidePages.currentIndex = 0
|
|
clientList.currentIndex = -1
|
|
actionList.currentIndex = -1
|
|
}
|
|
}
|