GODT-22: Facelift

- GODT-1199: Add menu to status window - GODT-22: use ColorImage instead of IconLabel - GODT-22: remove banners from MainWindow - GODT-1199: Fix separator width - GODT-1199: Fix StatusWindow button position - GODT-1198: Open main window on startup if no users - GODT-1199: Fix avatar text color - GODT-1198: refactor main window layout - GODT-22: add missing components to qmldir - GODT-22: refactor components having Layout as root item - GODT-22: add more user controls - GODT-1199: Add status window resize and maximum height - GODT-22: WIP: notification arch - GODT-22: Notifications WIP - GODT-22: Fix notification filter, topmost notification - GODT-1199: Add notifications to status window - GODT-22: Add strict typization to colorScheme variable - GODT-1198: WIP Notifications, dialogs and banners - GODT-22: Add backend notifications (Banners & Dialogs) D
2021-08-04 14:00:31 +02:00
parent 6bd0739013
commit 0a9748a15d
51 changed files with 3277 additions and 1056 deletions
--- a/internal/frontend/qml/Proton/ApplicationWindow.qml
+++ b/internal/frontend/qml/Proton/ApplicationWindow.qml
@ -0,0 +1,136 @@
+// Copyright (c) 2021 Proton Technologies AG
+//
+// This file is part of ProtonMail Bridge.
+//
+// ProtonMail Bridge is free software: you can redistribute it and/or modify
+// it under the terms of the GNU General Public License as published by
+// the Free Software Foundation, either version 3 of the License, or
+// (at your option) any later version.
+//
+// ProtonMail Bridge is distributed in the hope that it will be useful,
+// but WITHOUT ANY WARRANTY; without even the implied warranty of
+// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+// GNU General Public License for more details.
+//
+// You should have received a copy of the GNU General Public License
+// along with ProtonMail Bridge.  If not, see <https://www.gnu.org/licenses/>.
+
+import QtQml 2.12
+import QtQuick 2.12
+import QtQuick.Window 2.12
+import QtQuick.Controls 2.12
+import QtQuick.Controls.impl 2.12
+import QtQuick.Templates 2.12 as T
+
+import "."
+
+T.ApplicationWindow {
+    id: root
+
+    property ColorScheme colorScheme
+
+    // popup priority based on types
+    enum PopupType {
+        Banner = 0,
+        Dialog = 1
+    }
+
+    // contains currently visible popup
+    property var popupVisible: null
+
+    // list of all popups within ApplicationWindow
+    property ListModel popups: ListModel {
+        // overriding get method to ignore any role and return directly object itself
+        function get(row) {
+            if (row < 0 || row >= count) {
+                return undefined
+            }
+            return data(index(row, 0), Qt.DisplayRole)
+        }
+
+        onRowsInserted: {
+            for (var i = first; i <= last; i++) {
+                var obj = popups.get(i)
+                obj.onShouldShowChanged.connect( root.processPopups )
+            }
+
+            processPopups()
+        }
+
+        onRowsAboutToBeRemoved: {
+            for (var i = first; i <= last; i++ ) {
+                var obj = popups.get(i)
+                obj.onShouldShowChanged.disconnect( root.processPopups )
+
+                // if currently visible popup was removed
+                if (root.popupVisible === obj) {
+                    root.popupVisible.visible = false
+                    root.popupVisible = null
+                }
+            }
+
+            processPopups()
+        }
+    }
+
+    function processPopups() {
+        if ((root.popupVisible) && (!root.popupVisible.shouldShow)) {
+            root.popupVisible.visible = false
+        }
+
+        // do nothing if there is already visible popup
+        if (root.popupVisible) {
+            return
+        }
+
+        var topmost = null
+        for (var i = 0; i < popups.count; i++) {
+            var obj = popups.get(i)
+
+            if (obj.shouldShow === false) {
+                continue
+            }
+
+            if (topmost && (topmost.popupType > obj.popupType)) {
+                continue
+            }
+
+            if (topmost && (topmost.popupType === obj.popupType) && (topmost.occurred > obj.occurred)) {
+                continue
+            }
+
+            topmost = obj
+        }
+
+        root.popupVisible = topmost
+
+        if (!topmost) {
+            return
+        }
+
+        topmost.visible = true
+    }
+
+    Connections {
+        target: root.popupVisible
+
+        onVisibleChanged: {
+            if (root.popupVisible.visible) {
+                return
+            }
+
+            root.popupVisible = null
+            root.processPopups()
+        }
+    }
+
+    color: root.colorScheme.background_norm
+
+    overlay.modal: Rectangle {
+        color: root.colorScheme.backdrop_norm
+    }
+
+    overlay.modeless: Rectangle {
+        color: "transparent"
+    }
+}