proton-bridge/internal/frontend/qt6/CMakeLists.txt

# Copyright (c) 2022 Proton AG
#
# This file is part of Proton Mail Bridge.
#
# Proton Mail Bridge is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# Proton Mail Bridge is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with Proton Mail Bridge. If not, see <https://www.gnu.org/licenses/>.

cmake_minimum_required(VERSION 3.22)

set(CMAKE_OSX_ARCHITECTURES x86_64) # needs to be set before the first project() directive.

#We rely on vcpkg for to get gRPC+Protobuf
if (NOT DEFINED ENV{VCPKG_ROOT})
    message(FATAL_ERROR "vcpkg is required. Install vcpkg and define VCPKG_ROOT to point the the vcpkg installation folder. (e.g. ~/vcpkg/")
endif()
if (APPLE)
    set(VCPKG_TARGET_TRIPLET x64-osx)
endif()
if  (WIN32)
    set(VCPKG_TARGET_TRIPLET x64-mingw-static)
endif()
set(CMAKE_TOOLCHAIN_FILE "$ENV{VCPKG_ROOT}/scripts/buildsystems/vcpkg.cmake" CACHE STRING "toolchain")


project(bridge_qt6 LANGUAGES CXX)
if (APPLE) # On macOS, we have some Objective-C++ code in DockIcon to deal with ... the dock icon.
    enable_language(OBJC OBJCXX)
endif()

if (NOT DEFINED ENV{QT5DIR})
    message(FATAL_ERROR "QT5DIR needs to be defined and point to the root of your Qt5 folder (e.g. /Users/MyName/Qt/5.10.1/clang_64).")
endif()


set(CMAKE_PREFIX_PATH $ENV{QT5DIR} ${CMAKE_PREFIX_PATH})
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTORCC ON)
set(CMAKE_AUTOUIC ON)
find_package(Protobuf CONFIG REQUIRED)
message(STATUS "Using protobuf ${Protobuf_VERSION}")


find_package(grpc CONFIG REQUIRED)
message(STATUS "Using gRPC ${gRPC_VERSION}")


if (APPLE) # We need to link the Cocoa framework for the dock icon.
    find_library(COCOA_LIBRARY Cocoa REQUIRED)
endif()


find_package(Qt5 COMPONENTS
    Core
    Quick
    Qml
    QuickControls2
    REQUIRED)

find_program(PROTOC_EXE protoc)
find_program(GRPC_CPP_PLUGIN grpc_cpp_plugin)
set(PROTO_DIR  "${CMAKE_CURRENT_SOURCE_DIR}/../grpc")
set(PROTO_FILE "${PROTO_DIR}/bridge.proto")
set(GRPC_OUT_DIR "${CMAKE_CURRENT_SOURCE_DIR}/GRPC")
set(PROTO_CPP_FILE "${GRPC_OUT_DIR}/bridge.pb.cc")
set(PROTO_H_FILE "${GRPC_OUT_DIR}/bridge.pb.h")
set(GRPC_CPP_FILE "${GRPC_OUT_DIR}/bridge.grpc.pb.cc")
set(GRPC_H_FILE "${GRPC_OUT_DIR}/bridge.grpc.pb.h")
if (APPLE)
    set(DOCK_ICON_SRC_FILE DockIcon/DockIcon.mm)
else()
    set(DOCK_ICON_SRC_FILE DockIcon/DockIcon.cpp)
endif()

add_custom_command(
    OUTPUT
    ${PROTO_CPP_FILE}
    ${PROTO_H_FILE}
    ${GRPC_CPP_FILE}
    ${GRPC_H_FILE}
    COMMAND
    ${PROTOC_EXE}
    ARGS
    --proto_path=${PROTO_DIR}
    --plugin=protoc-gen-grpc="${GRPC_CPP_PLUGIN}"
    --cpp_out=${GRPC_OUT_DIR}
    --grpc_out=${GRPC_OUT_DIR}
    ${PROTO_FILE}
    DEPENDS
    ${PROTO_FILE}
    COMMENT "Generating gPRC/Protobuf C++ code"
)

add_executable(bridge_qt6
    ${PROTO_CPP_FILE} ${PROTO_H_FILE} ${GRPC_CPP_FILE} ${GRPC_H_FILE}
    AppController.cpp AppController.h
    EventStreamWorker.cpp EventStreamWorker.h
    Exception.cpp Exception.h
    Log.cpp Log.h
    main.cpp
    Pch.h
    QMLBackend.cpp QMLBackend.h
    ${DOCK_ICON_SRC_FILE} DockIcon/DockIcon.h
    GRPC/GRPCClient.cpp GRPC/GRPCClient.h
    GRPC/GRPCUtils.cpp GRPC/GRPCUtils.h
    User/User.cpp User/User.h User/UserList.cpp User/UserList.h
    Worker/Overseer.cpp Worker/Overseer.h
    Worker/Worker.h)

include_directories(${CMAKE_CURRENT_SOURCE_DIR})

target_precompile_headers(bridge_qt6 PRIVATE Pch.h)

target_link_libraries(bridge_qt6
    Qt5::Core
    Qt5::Quick
    Qt5::Qml
    Qt5::QuickControls2
    protobuf::libprotobuf
    gRPC::grpc++
    )

if (APPLE)
target_link_libraries(bridge_qt6 ${COCOA_LIBRARY})
endif()