forked from Silverfish/proton-bridge
0a9748a15d
- GODT-1199: Add menu to status window - GODT-22: use ColorImage instead of IconLabel - GODT-22: remove banners from MainWindow - GODT-1199: Fix separator width - GODT-1199: Fix StatusWindow button position - GODT-1198: Open main window on startup if no users - GODT-1199: Fix avatar text color - GODT-1198: refactor main window layout - GODT-22: add missing components to qmldir - GODT-22: refactor components having Layout as root item - GODT-22: add more user controls - GODT-1199: Add status window resize and maximum height - GODT-22: WIP: notification arch - GODT-22: Notifications WIP - GODT-22: Fix notification filter, topmost notification - GODT-1199: Add notifications to status window - GODT-22: Add strict typization to colorScheme variable - GODT-1198: WIP Notifications, dialogs and banners - GODT-22: Add backend notifications (Banners & Dialogs) D
255 lines
8.8 KiB
QML
255 lines
8.8 KiB
QML
// Copyright (c) 2021 Proton Technologies AG
|
|
//
|
|
// This file is part of ProtonMail Bridge.
|
|
//
|
|
// ProtonMail Bridge is free software: you can redistribute it and/or modify
|
|
// it under the terms of the GNU General Public License as published by
|
|
// the Free Software Foundation, either version 3 of the License, or
|
|
// (at your option) any later version.
|
|
//
|
|
// ProtonMail Bridge is distributed in the hope that it will be useful,
|
|
// but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
// GNU General Public License for more details.
|
|
//
|
|
// You should have received a copy of the GNU General Public License
|
|
// along with ProtonMail Bridge. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
import QtQuick 2.12
|
|
import QtQuick.Controls 2.12
|
|
import QtQuick.Controls.impl 2.12
|
|
import QtQuick.Templates 2.12 as T
|
|
import "."
|
|
|
|
T.Button {
|
|
property ColorScheme colorScheme
|
|
|
|
property alias secondary: control.flat
|
|
readonly property bool primary: !secondary
|
|
readonly property bool isIcon: control.text === ""
|
|
|
|
property bool loading: false
|
|
|
|
property bool borderless: false
|
|
|
|
property int labelType: Label.LabelType.Body
|
|
|
|
// TODO: store previous enabled state and restore it?
|
|
// For now assuming that only enabled buttons could have loading state
|
|
onLoadingChanged: {
|
|
if (loading) {
|
|
enabled = false
|
|
} else {
|
|
enabled = true
|
|
}
|
|
}
|
|
|
|
id: control
|
|
|
|
implicitWidth: Math.max(
|
|
implicitBackgroundWidth + leftInset + rightInset,
|
|
implicitContentWidth + leftPadding + rightPadding
|
|
)
|
|
implicitHeight: Math.max(
|
|
implicitBackgroundHeight + topInset + bottomInset,
|
|
implicitContentHeight + topPadding + bottomPadding
|
|
)
|
|
|
|
padding: 8
|
|
horizontalPadding: 16
|
|
spacing: 10
|
|
|
|
font: label.font
|
|
|
|
icon.width: 16
|
|
icon.height: 16
|
|
icon.color: {
|
|
if (primary && !isIcon) {
|
|
return "#FFFFFF"
|
|
} else {
|
|
return control.colorScheme.text_norm
|
|
}
|
|
}
|
|
|
|
contentItem: Item {
|
|
id: _contentItem
|
|
|
|
// Since contentItem is allways resized to maximum available size - we need to "incapsulate" label
|
|
// and icon within one single item with calculated fixed implicit size
|
|
|
|
implicitHeight: labelIcon.implicitHeight
|
|
implicitWidth: labelIcon.implicitWidth
|
|
|
|
Item {
|
|
id: labelIcon
|
|
|
|
anchors.horizontalCenter: _contentItem.horizontalCenter
|
|
anchors.verticalCenter: _contentItem.verticalCenter
|
|
|
|
width: Math.min(implicitWidth, control.availableWidth)
|
|
height: Math.min(implicitHeight, control.availableHeight)
|
|
|
|
implicitWidth: {
|
|
var textImplicitWidth = control.text !== "" ? label.implicitWidth : 0
|
|
var iconImplicitWidth = iconImage.source ? iconImage.implicitWidth : 0
|
|
var spacing = (control.text !== "" && iconImage.source && control.display === AbstractButton.TextBesideIcon) ? control.spacing : 0
|
|
|
|
return control.display === AbstractButton.TextBesideIcon ? textImplicitWidth + iconImplicitWidth + spacing : Math.max(textImplicitWidth, iconImplicitWidth)
|
|
}
|
|
implicitHeight: {
|
|
var textImplicitHeight = control.text !== "" ? label.implicitHeight : 0
|
|
var iconImplicitHeight = iconImage.source ? iconImage.implicitHeight : 0
|
|
var spacing = (control.text !== "" && iconImage.source && control.display === AbstractButton.TextUnderIcon) ? control.spacing : 0
|
|
|
|
return control.display === AbstractButton.TextUnderIcon ? textImplicitHeight + iconImplicitHeight + spacing : Math.max(textImplicitHeight, iconImplicitHeight)
|
|
}
|
|
|
|
Label {
|
|
colorScheme: root.colorScheme
|
|
id: label
|
|
anchors.left: labelIcon.left
|
|
anchors.top: labelIcon.top
|
|
anchors.bottom: labelIcon.bottom
|
|
anchors.right: control.loading ? iconImage.left : labelIcon.right
|
|
anchors.rightMargin: control.loading ? control.spacing : 0
|
|
|
|
elide: Text.ElideRight
|
|
horizontalAlignment: Qt.AlignHCenter
|
|
verticalAlignment: Qt.AlignVCenter
|
|
|
|
text: control.text
|
|
color: {
|
|
if (primary && !isIcon) {
|
|
return "#FFFFFF"
|
|
} else {
|
|
return control.colorScheme.text_norm
|
|
}
|
|
}
|
|
opacity: control.enabled || control.loading ? 1.0 : 0.5
|
|
|
|
type: labelType
|
|
}
|
|
|
|
ColorImage {
|
|
id: iconImage
|
|
|
|
anchors.verticalCenter: labelIcon.verticalCenter
|
|
anchors.right: labelIcon.right
|
|
|
|
width: {
|
|
// special case for loading since we want icon to be square for rotation animation
|
|
if (control.loading) {
|
|
return Math.min(control.icon.width, availableWidth, control.icon.height, availableHeight)
|
|
}
|
|
|
|
return Math.min(control.icon.width, availableWidth)
|
|
}
|
|
height: {
|
|
if (control.loading) {
|
|
return width
|
|
}
|
|
|
|
Math.min(control.icon.height, availableHeight)
|
|
}
|
|
|
|
color: control.icon.color
|
|
source: control.loading ? "../icons/Loader_16.svg" : control.icon.source
|
|
visible: control.loading || control.icon.source
|
|
|
|
RotationAnimation {
|
|
target: iconImage
|
|
loops: Animation.Infinite
|
|
duration: 1000
|
|
from: 0
|
|
to: 360
|
|
direction: RotationAnimation.Clockwise
|
|
running: control.loading
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
background: Rectangle {
|
|
implicitWidth: 36
|
|
implicitHeight: 36
|
|
radius: 4
|
|
visible: true
|
|
color: {
|
|
if (!isIcon) {
|
|
if (primary) {
|
|
// Primary colors
|
|
|
|
if (control.down) {
|
|
return control.colorScheme.interaction_norm_active
|
|
}
|
|
|
|
if (control.enabled && (control.highlighted || control.hovered || control.checked)) {
|
|
return control.colorScheme.interaction_norm_hover
|
|
}
|
|
|
|
if (control.loading) {
|
|
return control.colorScheme.interaction_norm_hover
|
|
}
|
|
|
|
return control.colorScheme.interaction_norm
|
|
} else {
|
|
// Secondary colors
|
|
|
|
if (control.down) {
|
|
return control.colorScheme.interaction_default_active
|
|
}
|
|
|
|
if (control.enabled && (control.highlighted || control.hovered || control.checked)) {
|
|
return control.colorScheme.interaction_default_hover
|
|
}
|
|
|
|
if (control.loading) {
|
|
return control.colorScheme.interaction_default_hover
|
|
}
|
|
|
|
return control.colorScheme.interaction_default
|
|
}
|
|
} else {
|
|
if (primary) {
|
|
// Primary icon colors
|
|
|
|
if (control.down) {
|
|
return control.colorScheme.interaction_default_active
|
|
}
|
|
|
|
if (control.enabled && (control.highlighted || control.hovered || control.checked)) {
|
|
return control.colorScheme.interaction_default_hover
|
|
}
|
|
|
|
if (control.loading) {
|
|
return control.colorScheme.interaction_default_hover
|
|
}
|
|
|
|
return control.colorScheme.interaction_default
|
|
} else {
|
|
// Secondary icon colors
|
|
|
|
if (control.down) {
|
|
return control.colorScheme.interaction_default_active
|
|
}
|
|
|
|
if (control.enabled && (control.highlighted || control.hovered || control.checked)) {
|
|
return control.colorScheme.interaction_default_hover
|
|
}
|
|
|
|
if (control.loading) {
|
|
return control.colorScheme.interaction_default_hover
|
|
}
|
|
|
|
return control.colorScheme.interaction_default
|
|
}
|
|
}
|
|
}
|
|
|
|
border.color: control.colorScheme.border_norm
|
|
border.width: secondary && !borderless ? 1 : 0
|
|
|
|
opacity: control.enabled || control.loading ? 1.0 : 0.5
|
|
}
|
|
}
|